home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d8
/
qns310.arc
/
Q-RELAY.SCR
< prev
next >
Wrap
Text File
|
1991-04-28
|
3KB
|
78 lines
;┌──────────────────────────────────────────────────────────────────────────┐
;│ Q-RELAY.SCR Copyright 1988-1990 by Rik Brown │
;│ │
;│ PCRELAY hub door script │
;└──────────────────────────────────────────────────────────────────────────┘
IF "$4" = "$maxulmail" LOGOFF ; Counter check: ul attempts
INCR 4 ; Increment mail upload counter
SEND "^~OPEN $maildoor^M" ; Open netmail door
WHEN ; Clear all WHENs
WHEN "assword to" "^~^~^~$mailpswd^M" ; "password to open the DOOR"
WHEN "assword for" "^~^~^~$mailpswd^M" ; "Incorrect Password for DOOR"
WHEN "(Dots will echo)" PCBCOMMAND ; Means dumped out of door
WHEN "NO CARRIER" DIALSEQUENCE ; Error handling (carrier loss)
TIMEOUT 30 DIALSEQUENCE ; Wait max 30 secs for next line
WAITFOR "*"
ULMAIL:
IF "$4" = "$maxulmail" LOGOFF ; Counter check: ul attempts
INCR 4 ; Increment mail upload counter
DOS "qnssz.bat $maildir $mailul" ; Call transfer BAT file
IF $OFFLINE DIALSEQUENCE ; Error handling (carrier loss)
CLRSCR ; Exit DSZ status line
EXIST $maildir\SUCCESS.SND DLMAIL ; Set to your location
GOTO ULMAIL
DLMAIL:
EXIST $maildir\SUCCESS.RCV LOGOFF ; Error handling (prior carrier loss)
IF "$3" = "$maxDLMAIL" LOGOFF ; Counter check: dl attempts
INCR 3 ; Increment DLMAIL counter
TIMEOUT 30 LOGOFF ; Keep large
WAITFOR "*"
TIMEOUT 1000 DIALSEQUENCE ; Wait max 10 minutes for download
DOS "if exist $maildir\$mailDL del $maildir\$mailDL"
; Delete any prior non-completed Zmodem download of mail
DOS "qnsrz.bat $maildir $mailDL" ; Call transfer BAT file
IF $OFFLINE DIALSEQUENCE ; Error handling (carrier loss)
CLRSCR ; Exit DSZ status line
EXIST $maildir\SUCCESS.RCV SUCCESS ; Transfers succeeded both wasy
GOTO DLMAIL ; Try again if unsuccessful
SUCCESS:
NOTE
NOTE ----------------------------------------------------------------------
NOTE SUCCESSFUL UP AND DOWNLOAD OF RELAY MAIL PACKETS. LOGGING OFF....
NOTE ----------------------------------------------------------------------
NOTE
; ALT-255 at end of 1st and last NOTE line above (do not alter)
DOS "if exist $maildir\SUCCESS.RCV del $maildir\$mailUL"
; The above line should not be reached unless both the send and receive of
; mail was successful. Thereafter the send file will be deleted. But if there
; was an error, the send file will be uploaded the next time the script is
; run. In this way no replies are lost. Pending mail files must be success-
; fully uploaded before a totally new upload file can be created.
RETURN
PCBCOMMAND:
SEND "^~^~$pword^M"
SCRIPT Q-LOGOFF.SCR
DIALSEQUENCE:
SCRIPT Q-LOGON.SCR
LOGOFF:
SCRIPT Q-LOGOFF.SCR